# 推荐充能：雷电将军: 180-220%，香菱：180-200%，夏沃蕾，菲谢尔：无要求。

raiden char lvl=90/90 cons=0 talent=9,9,9; 
raiden add weapon="deathmatch" refine=1 lvl=90/90;
raiden add set="emblemofseveredfate" count=5;
raiden add stats hp=4780 atk=311 er=0.518 atk%=0.466 cd=0.622 ; 
raiden add stats atk%=0.4 er=0.11 em=40 cr=0.363 cd=0.462;

fischl char lvl=90/90 cons=6 talent=9,9,9; 
fischl add weapon="stringless" refine=5 lvl=90/90;
fischl add set="gt" count=4;
fischl add stats hp=4780 atk=311 atk%=0.466 electro%=0.466 cr=0.311; 
fischl add stats atk%=0.4 em=40 cr=0.231 cd=0.726;

xiangling char lvl=90/90 cons=6 talent=9,9,9; 
xiangling add weapon="thecatch" refine=5 lvl=90/90;
xiangling add set="emblemofseveredfate" count=5;
xiangling add stats hp=4780 atk=311 atk%=0.466 pyro%=0.466 cr=0.311 ; 
xiangling add stats atk%=0.2 er=0.22 em=80 cr=0.198 cd=0.792;
                                
chevreuse char lvl=90/90 cons=6 talent=9,9,9;
chevreuse add weapon="favoniuslance" refine=5 lvl=90/90;
chevreuse add set="noblesse" count=4;
chevreuse add stats hp=4780 atk=311 hp%=0.466 hp%=0.466 hp%=0.466 ; 
chevreuse add stats hp%=0.5 er=0.33 em=40 cr=0.264 cd=0.132;
                                                              
#词条分布
#           hp%  atk%  em  er  cr  cd
#raiden      0    8    2   2   11  7
#fischl      0    8    2   0   7   11
#xiangling   0    4    4   4   6   12
#chevreuse   10   0    0   6   8   2

# 模拟当前充能最差环境, 12-3 水形幻人, 每 33% 血量掉 3 元素微粒, 对于非水系角色等于 1.5 微粒
target lvl=100 resist=0.1 radius=2 pos=0,2.4 hp=3050301 particle_threshold=1016767 particle_drop_count=1.5;
options swap_delay=12 iteration=1000;

active raiden;

raiden skill;

while 1 {
  if .chevreuse.burst.ready { chevreuse burst; } else { chevreuse attack:2; }
  # 因为循环末尾有夏沃蕾 e 给香菱打球环节, 夏沃蕾 e cd 15s, 所以只有首轮可以双 e
  if .chevreuse.skill.ready { chevreuse skill[hold=1]; } else { chevreuse attack; }
  xiangling burst; 
  # 香菱战技原理同上, 双 e cd 大于循环时间
  if .xiangling.skill.ready { xiangling skill, dash; }
  fischl attack:2, burst;
  # 雷神这种手法是为了最大限度触发菲谢尔天赋 2 和 6 命
  raiden burst, attack:4, dash, attack:4, dash, attack:4, skill, attack:4;
  chevreuse attack, skill[hold=1], attack;
  xiangling attack:2, skill, dash;
  if .fischl.skill.ready {
    fischl attack:3, skill;
  } else {
    fischl attack:4, dash;
  } 
}